入力したデータを分離ストレージに保存し、一覧で表示する

ロジックコードを記述する

リスト2　(MainPage.xaml.vb)

Option Strict On
Imports System.Xml.Linq
Imports System.IO

仮想ファイルシステムを作成および使用するための型が含まれている、System.IO.IsolatedStorage名前空間をインポートします。分離ストレージによって、安全なクライアント側のストレージが提供されます。
Imports System.IO.IsolatedStorage
Partial Public Class MainPage
  Inherits PhoneApplicationPage
  ' コンストラクター
  Public Sub New()
    InitializeComponent()
  End Sub

Sharedキーワードでデータの番号となるメンバ変数numberを宣言しておきます。
  Shared number As Integer = 1

ページがアクティブになった時呼び出されるメソッド

変数storageを、ファイルとディレクトリを格納している分離ストレージ領域を表すIsolateStorageFileクラスとして宣言します。Path.Combineで、PersonalInfoというフォルダ名と、PersonalInfo.xmlというXMLファイルを連結し、filePath変数に格納しておきます。
FileExistsメソッドでXMLファイルが存在しているかどうかをチェックし、存在している場合は以下の処理を実行します。
[データ一覧]ボタンの使用を可能にします。IsolatedStorageFileクラスのOpenFileメソッドでPersonalInfoフォルダ内のPersonalInfo.xmlファイルを、指定したファイルアクセスを使用して指定したモードでファイルを開きます。開いたファイルをStreamReaderで読み込みます。ReadToEndメソッドでファイルの最後まで読み取り、変数readXmldoc変数に格納しておきます。読み込んだXMLテキストをParseメソッドでXElementとして読み込みます。<情報>要素の子要素<番号>の値を取得し、変数getNumberに格納します。Integer.Parseメソッドで取得した「番号」を数値に変換し、1を加算し、メンバ変数numberに格納しておきます。PersonalInfoフォルダにPersonalInfo.xmlファイルが存在しない場合は、[データ一覧]ボタンの使用は不可のままです。
noTextBoxにメンバ変数numberの値を文字列に変換して表示します。
後ほど作成する、DataIchiranPage.xamlから渡された文字データを受け取ります。文字データはNavigationContextのQueryStringにDictionaryとして提供されます。ContainsKeyメソッドで指定したキーがDictionaryに格納されているかどうかを判断します。この場合はIndexというキーがDictionaryに格納されているかどうかを判断し、格納されている場合は以下の処理を実行します。
文字データとしてのIndexで渡された値を数値に変換して、変数Indexに格納します。Indexの値が0より小さい場合は処理を抜けます。IsolatedStorageFileクラスのOpenFileメソッドでPersonalInfoフォルダ内のPersonalInfo.xmlファイルを、指定したファイルアクセスを使用して指定したモードでファイルを開きます。開いたファイルをStreamReaderで読み込みます。ReadToEndメソッドでファイルの最後まで読み取り、変数readXmldoc変数に格納しておきます。読み込んだXMLテキストをParseメソッドでXElementとして読み込みます。
変数Indexに該当する<情報>要素の子要素の内容テキストを取得し、各TextBoxのTextプロパティに指定します。データ一覧から選択されたインデックスに該当するデータがTextBoxに表示されます。[保存]ボタンは使用不可となり、[新規]ボタンは使用可能となります。
  Protected Overrides Sub OnNavigatedTo(e As System.Windows.Navigation.NavigationEventArgs)
    Dim Index As Integer
    Dim storage As IsolatedStorageFile = IsolatedStorageFile.GetUserStoreForApplication
    Dim filePath As String = Path.Combine("PersonalInfo", "PersonalInfo.xml")
    If storage.FileExists(filePath) = True Then
      ichiranButton.IsEnabled = True
      Using stream As IsolatedStorageFileStream = storage.OpenFile(filePath, FileMode.Open, FileAccess.Read)
      Using reader As StreamReader = New StreamReader(stream, System.Text.Encoding.UTF8)
        Dim readXmldoc As String = reader.ReadToEnd
        Dim xmldoc As XElement = XElement.Parse(readXmldoc)
        Dim getNumber As String = xmldoc.Descendants("情報").Elements("番号").Last.Value
        number = Integer.Parse(getNumber) + 1
      End Using
    End Using
 
  Else
    ichiranButton.IsEnabled = False
  End If
  noTextBlock.Text = number.ToString
 
  Dim myParam As IDictionary(Of String, String) = NavigationContext.QueryString
  If myParam.ContainsKey("Index") = True Then
    Index = Integer.Parse(myParam("Index"))
    If Index < 0 Then Exit Sub
    Using myStream As IsolatedStorageFileStream = storage.OpenFile(filePath, FileMode.Open, FileAccess.Read)
      Using reader As StreamReader = New StreamReader(myStream, System.Text.Encoding.UTF8)
        Dim readXmldoc As String = reader.ReadToEnd
        Dim doc As XElement = XElement.Parse(readXmldoc)
        noTextBlock.Text = doc.Descendants("情報")(Index).Element("番号").Value
        nameTextBox.Text = doc.Descendants("情報")(Index).Element("氏名").Value
        addressTextBox.Text = doc.Descendants("情報")(Index).Element("住所").Value
        telTextBox.Text = doc.Descendants("情報")(Index).Element("電話").Value
        mailTextBox.Text = doc.Descendants("情報")(Index).Element("E-mail").Value
 
        saveButton1.IsEnabled = False
        newButton.IsEnabled = True
      End Using
    End Using
  End If
  MyBase.OnNavigatedTo(e) 
End Sub

[保存]ボタンがタップされた時の処理

変数storageを、ファイルとディレクトリを格納している分離ストレージ領域を表すIsolateStorageFileクラスとして宣言します。DirectryExistsメソッドでPersonalInfoというフォルダが存在しているかどうかをチェックし、存在していない場合は、CreateDirectoryメソッドでPersonalInfoというフォルダを作成します。
Path.CombineでPersonalInfoというフォルダとPersonalInfo.xmlファイルとを連結します。PeronalInfoフォルダ内にPersonalInfo.xmlが存在しない場合、つまり、1番目のデータが入力されてPersonalInfo.xmlファイルとして保存される場合の処理です。
Visual Basic の埋め込み式を用いて、XML宣言とルート要素<個人情報>、その子要素として<情報>、<情報>要素の子要素として、<番号>、<氏名>、<住所>、<電話>、<E-mail>を作成し、内容テキストとして、埋め込み式の構文である <%= expression %>を用いて各TextBoxに入力された値を指定します。これは ASP.NET で使用される構文と同じです。
分離ストレージ内のファイルを表すIsolatedStorageFileStreamクラス用オブジェクト変数streamを用意し、IsolatedStorageFile.CreateFileメソッドで、分離ストレージ内にfilePath変数の持っているフォルダ名付きXMLファイルを作成します。PersonalInfoフォルダ内にPersonalInfo.xmlファイルが存在する場合は、新しいStreamWriter 生成し、IsolatedStorageFile.OpenFileメソッドで、指定したファイルアクセスを使用して指定したモードでファイルを開き、初期化します。Writeメソッドで埋め込み式のXMLをストリームに書き込みます。保存した旨のメッセージを表示します。
次は、既にPersonalInfoフォルダ内にPersonalInfo.xmlが存在する場合の処理です。
分離ストレージ内のファイルを表すIsolatedStorageFileStreamクラス用オブジェクト変数myStreamを用意し、IsolatedStorageFileクラスのOpenFileメソッドでPersonalInfoフォルダ内のPersonalInfo.xmlファイルを、指定したファイルアクセスを使用して指定したモードでファイルを開きます。開いたファイルをStreamReaderで読み込みます。ReadToEndメソッドでファイルの最後まで読み取り変数readXmldoc変数に格納しておきます。読み込んだXMLテキストをParseメソッドでXElementとして読み込みます。
追加する<情報>要素とその子要素を、埋め込み式を用いて生成し、各要素の値に各TextBoxに入力された値を指定します。新しく生成したXML要素を、読み込んだXMLにAddメソッドで追加します。IsolatedStorageFileStreamを閉じます。
PersonalInfo.xmlファイルが存在する場合は、新しいStreamWriter 生成し、IsolatedStorageFile.OpenFileメソッドで、指定したファイルアクセスを使用して指定したモードでファイルを開き、初期化します。Writeメソッドで、新しいXML要素の追加されたXMLをストリームに書き込みます。保存した旨のメッセージを表示します。
入力ボックス内を空にするDataClearプロシジャを実行します。メンバ変数numberを1つ加算します。加算したnumber変数の値を文字列に変換して、noTextBlockに表示します。
  Private Sub saveButton1_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles saveButton1.Click
    Dim storage As IsolatedStorageFile = IsolatedStorageFile.GetUserStoreForApplication
    If storage.DirectoryExists("PersonalInfo") = False Then
       storage.CreateDirectory("PersonalInfo")
    End If
    Dim filePath As String = Path.Combine("PersonalInfo", "PersonalInfo.xml")
    If storage.FileExists(filePath) = False Then
      Dim xmldoc As XDocument = <?xml version="1.0" encoding="utf-8"?>
                                <個人情報>
                                  <情報>
                                    <番号><%= noTextBlock.Text %></番号>
                                    <氏名><%= nameTextBox.Text %></氏名>
                                    <住所><%= addressTextBox.Text %></住所>
                                    <電話><%= telTextBox.Text %></電話>
                                    <E-mail><%= mailTextBox.Text %></E-mail>
                                  </情報>
                                </個人情報>

      Using stream As IsolatedStorageFileStream = storage.CreateFile(filePath)
      End Using
        If storage.FileExists(filePath) = True Then
          Using writer As StreamWriter = New StreamWriter(storage.OpenFile(filePath, FileMode.Open, FileAccess.Write))
            writer.Flush()
            writer.Write(xmldoc.ToString)
            MessageBox.Show("保存しました。")
            ichiranButton.IsEnabled = True
          End Using 
        End If
      Else
        Dim myStream As IsolatedStorageFileStream = storage.OpenFile(filePath, FileMode.Open, FileAccess.Read)
        Using reader As StreamReader = New StreamReader(myStream, System.Text.Encoding.UTF8)
          Dim readXmldoc As String = reader.ReadToEnd
          Dim doc As XElement = XElement.Parse(readXmldoc)
          Dim addXml As XElement = <情報>
                                     <番号><%= noTextBlock.Text %></番号>
                                     <氏名><%= nameTextBox.Text %></氏名>
                                     <住所><%= addressTextBox.Text %></住所>
                                     <電話><%= telTextBox.Text %></電話>
                                     <E-mail><%= mailTextBox.Text %></E-mail>
                                   </情報>
          doc.Add(addXml)
          myStream.Close()
 
          If storage.FileExists(filePath) = True Then
            Using writer As StreamWriter = New StreamWriter(storage.OpenFile(filePath, FileMode.Open, FileAccess.Write))
              writer.Flush()
              writer.Write(doc.ToString)
              MessageBox.Show("保存しました。")
            End Using
          End If
        End Using
      End If
 
      DataClear()
      number = number + 1
      noTextBlock.Text = number.ToString
    End Sub

全てのTextBox内を空にして、次のデータが入力できるようにするプロシージャ

  Private Sub DataClear()
    nameTextBox.Text = String.Empty
    addressTextBox.Text = String.Empty
    telTextBox.Text = String.Empty
    mailTextBox.Text = String.Empty
  End Sub

[データ一覧]ボタンがタップされた時の処理

これから作成する、DataIchiranPage.xamlに遷移します。
  Private Sub ichiranButton_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles ichiranButton.Click
    NavigationService.Navigate(New Uri("/DataIchiranPage.xaml", UriKind.Relative))
  End Sub

[キャンセル]ボタンがタップされた時の処理

DataClearプロシージャを実行します。
  Private Sub cancelButton_Click(sender As Object, e As System.Windows.RoutedEventArgs) Handles cancelButton.Click
    DataClear()
  End Sub

[新規]ボタンがタップされた時の処理

自分自身のページに遷移します。
  Private Sub newButton_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles newButton.Click
    NavigationService.Navigate(New Uri("/MainPage.xaml", UriKind.Relative))
  End Sub
End Class