XML-RPCを利用したWeb API

連載 [第2回] :

2006年10月2日(月)

XML-RPCをPerlから使う

   XML-RPCは簡単なルールなので、Webへのアクセスさえできれば、後は全てを自前で処理しても、それほどむつかしくはありません。しかしPerlにはXML-RPCを利用するためのモジュールも用意されているので、それを利用することで、より簡単にAPIが利用できるようになります。CPANにはXML-RPCを利用するためのモジュールがいくつか登録されていますが、今回はRPC::XMLモジュールを利用して、Blogger API経由でブログの記事を登録するプログラムを書いてみることにします。

   Blogger APIはXML-RPCを利用して作成されたブログの記事の取得や登録を行うためのAPIの仕様です。その名のとおりもともとはBloggerというBlogサービスで使われ始めたものですが、Movable Typeなどでも利用され、標準的なAPIとなっています。なお、最近ではブログ関連のAPIとしてAtomPP（後述）が主流になってきています。Blogger自体もBlogger APIからAtomPPへ移行する予定ですが、Blogger API自体はまだまだ広く利用されています。

   Blogger APIではブログの記事の取得や編集に関して、以下のようなメソッドを提供します。

blogger.newPost
blogger.editPost
blogger.getUsersBlogs
blogger.getUserInfo
blogger.getTemplate
blogger.setTemplate

これらのメソッドについての仕様は、以下のページを参照してください。

http://www.blogger.com/developers/api/1_docs/

今回はこのうち、新しい記事を登録するblogger.newPostを利用して記事を登録するサンプルを作成してみることにします。

blogger.newPostでは、表2の6つのパラメータを渡します。

パラメータ	型	役割
appkey	string	BloggerにおいてAPI Keyを指定するためのものだが、現在は任意の文字列を入れればいい
blogid	string	ブログのID
username	string	ユーザー名
password	string	パスワード
content	string	記事の本文
publish	boolean	Trueを指定するとその場でブログの再構築が行われる

表2：blogger.newPostのパラメータ

これを利用して記事を登録するサンプルを前ページのリスト7に示します。ここではBloggerのURLを指定しています。

リスト7：blogger.newPostで投稿するサンプル


		#!/usr/bin/perl

		use strict;

		use warnings;

		use RPC::XML::Client;

		

		my $client = RPC::XML::Client->new(

		      'http://plant.blogger.com/api/RPC2');

		my $req = RPC::XML::request->new(

		  'blogger.newPost',

		  RPC::XML::string->new('0123456789ABCDEF'),

		  RPC::XML::string->new('ブログID'),

		  RPC::XML::string->new('ユーザー名'),

		  RPC::XML::string->new('パスワード'),

		  RPC::XML::string->new('内容'),

		  RPC::XML::boolean->new('true'),

		);

		my $res = $client->send_request($req);

		if( $res->is_fault ){

		    print "ERR: ".$res->value->{faultString}."\n";

		}else{

		    print "ID: ".$res->value."\n";

		}

   まずはRPC::XML::Clientクラスのインスタンスを作成します。その際のパラメータはアクセスするサーバーのエントリポイントです。続いてリクエストデータを保持するRPC::XML::requestクラスのインスタンスを生成します。その際にはアクセスするメソッド名とパラメータを指定します。パラメータは、型ごとにRPC::XML::booleanやRPC::XML::stringなどのクラスが用意されているので、それを利用します。

   そしてRPC::XML::Clientオブジェクトのsend_requestメソッドに、作成したRPC::XML::requestオブジェクトを渡せば、XML-RPCを利用したアクセスが行われます。結果は変数型のオブジェクト（RPC::XML::stringなど）として取得できます。

   blogger.newPostでは、正しく記事が投稿できた場合には記事IDが文字列として返ります。正しく処理ができたかどうかはis_faultというメソッドで判断でき、エラーになった場合はデータ型としてRPC::XML::faultという専用のクラスが利用されます。

   なお、これをもしRPC-XMLモジュールを利用せずにLWP::UserAgentだけを使って全て自前で処理するのであれば、リスト8のようになるでしょう。XML-RPCでやり取りされる情報はシンプルなので、XMLを単なるテキストと捉えてこのように処理してしまうことも可能です。

リスト8：LWP::UserAgentだけを使ってXML-RPCを実現する


		#!/usr/bin/perl

		use strict;

		use warnings;

		use LWP::UserAgent;

		use HTTP::Request;

		

		my $requestbody = <<"END";

		<?xml version="1.0" encoding="UTF-8"?>

		<methodCall>

		  <methodName>blogger.newPost</methodName>

		  <params>

		    <param>

		       <value><string>0123456789ABCDEF</string></value>

		    </param>

		    <param>

		       <value><string>ブログID</string></value>

		    </param>

		    <param>

		       <value><string>ユーザー名</string></value>

		    </param>

		    <param>

		       <value><string>パスワード</string></value>

		    </param>

		    <param>

		       <value><string>内容</string></value>

		    </param>

		    <param>

		       <value><boolean>1</boolean></value>

		    </param>

		  </params>

		</methodCall>

		END

		

		my $ua = LWP::UserAgent->new;

		$ua->agent('PerlSample/0.1');

		$ua->timeout(5);

		my $request = HTTP::Request->new(POST => 'http://plant.blogger.com/api/RPC2');

		$request->content_type('text/xml');

		$request->content($requestbody);

		my $response = $ua->request($request);

		my $content = $response->content;

		$content =~ /<value>(.+?)<\/value>/;

		print "ID:$1";